엑셀 SORT, SORTBY 함수 – 데이터 정렬하기

엑셀 2021 또는 Microsoft 365 버전에서는 동적 배열을 사용하여 간편하게 계산하기 위해서 FILTER, UNIQUE, SORT, SORTBY, SEQUENCE, SINGLE, RANDARRAY 새로운 함수가 추가되었습니다. 이번에는 범위 또는 배열의 내용을 정렬하는 SORT, SORTBY 함수에 대해서 알아보죠.

◎ 포스트 기준 – Microsoft 365 앱

1. 함수 구문

1. SORT 함수 구문 (마이크로소프트 문서)

▶ SORT 함수는 범위 또는 배열의 내용을 정렬합니다.

SORT(array,[sort_index],[sort_order],[by_col])

인수 이름	설명
array (필수)	정렬할 범위 또는 배열
[sort_index] (선택)	정렬할 행 또는 열을 나타내는 숫자
[sort_order] (선택)	오름차순의 경우 1(기본값), 내림차순의 경우 -1
[by_col] (선택)	행별로 정렬하려면 FALSE(기본값), 열로 정렬하려면 TRUE

→ SORT (범위, [기준열], [정렬순서], [정렬방향])

2. SORTBY 함수 구문 (마이크로소프트 문서)

▶ SORTBY 함수는 대응되는 범위 또는 배열의 값을 기준으로 범위 또는 배열의 내용을 정렬합니다.

SORTBY(array, by_array1, [sort_order1], [by_array2, sort_order2],…)

인수 이름	설명
array (필수)	정렬할 배열 또는 범위
by_array1 (필수)	정렬의 기준이 되는 배열 또는 범위
[sort_order1] (선택)	정렬에 사용할 순서. 1은 오름차순, -1은 내림차순 기본값은 오름차순입니다.
[by_array2] (선택)	정렬의 기준이 되는 배열 또는 범위
[sort_order2] (선택)	정렬에 사용할 순서. 1은 오름차순, -1은 내림차순 기본값은 오름차순입니다.

→ SORTBY (범위, 기준범위1, [정렬순서1], [기준범위2], [정렬순서2], …)

☆ SORT 함수는 범위 내에서 특정(하나의) 열을 기준으로만 정렬하지만 SORTBY 함수는 범위 내에서 여러 열을 기준으로 정렬할 수 있고 다른 범위를 참조하여 정렬할 수도 있습니다.

2. SORT 함수 사용 예제

1. 예제 : [학생 정보] 범위에서 성명, 학과, 사는곳(내림차순) 각각 정렬하기

[사용 예제]

▶ [G4] : =SORT(B4:B12)

▶ [H4] : =SORT(D4:D12)

▶ [I4] : =SORT(E4:E12, , -1) 또는 =SORT(E4:E12, 1, -1)

2. 예제 : [학생 정보] 범위에서 “학년” 기준으로 “내림차순” 정렬하기

[사용 예제]

▶ [K4] : =SORT(A4:E12, 3, -1)

→ A4:E12 : 학생 정보 범위

→ 3 : 학년 (※ 1:학번, 2:성명, 3:학년, 4:학과, 5:사는곳) 기준으로 정렬

→ -1 : 내림차순

3. 예제 : [학생 정보] 범위에서 “서울”에 사는 학생정보를 “학번” 기준으로 정렬하기

[사용 예제]

▶ [Q4] : =SORT(FILTER(A4:E12,E4:E12=”서울”), 1)

→ FILTER(A4:E:12, E:4:E12=”서울) : 학생정보 범위에서 사는곳 “서울” 필터링

→ 1 : 학번 (※ 1:학번, 2:성명, 3:학년, 4:학과, 5:사는곳) 기준으로 정렬

3. SORTBY 함수 사용 예제

1. 예제 : [학생 정보] 범위에서 “학년(오름차순)”, “학과(오름차순)” 기준으로 정렬하기

[사용 예제]

▶ [W4] : =SORTBY(A4:E12,C4:C12,1,D4:D12,1)

→ A4:E:12 : 학생정보 범위

→ C4:C12, 1 : “학년” 기준으로 “1:오름차순” 정렬

→ D4:D12, 1 : “학과” 기준으로 “1:오름차순” 정렬

2. 예제 : [학생 정보] 범위에서 학과, 사는곳을 “학년” 기준으로 정렬하기 (참조)

[사용 예제]

▶ [AC4] : =SORTBY(D4:E12,C4:C12,1)

→ D4:E12 : 학과, 사는곳 범위

→ C4:C12 : 학년 기준으로 정렬

→ 1 : 오름차순

관련 이전 게시글

• 엑셀 FILTER 함수 – 원하는 여러 조건으로 데이터 필터링 하기
• 엑셀 UNIQUE 함수 – 중복 제거 고유 값 구하기

이 글이 도움이 되셨다면 공유를 부탁 드립니다. 다음 글에서 뵙겠습니다!